Motion on a Ring

SetOptions[Plot,
PlotRange->{{0,7},{0,0.5}},
PlotStyle->{{Blue,Thick},{Red,Thick},{Black,Thick},{Green,Thick}},
AxesLabel->{"ϕ","𝒫(ϕ)"},
ImageSize->400,
BaseStyle->{FontFamily->"Arial",FontSize->16},AxesStyle->Directive[FontFamily->"Arial",FontSize->16,Black,AbsoluteThickness[0.5],Arrowheads[0.04]],TicksStyle->{{Black,AbsoluteThickness[0.5]},{Black,AbsoluteThickness[0.5]}}];
SetOptions[ParametricPlot3D,
Mesh->False,
AxesLabel->{"x","y",None},
ImageSize->400,
AxesStyle->Directive[FontFamily->"Arial",FontSize->16,Black,AbsoluteThickness[0.5]],
ColorFunctionScaling->False,
Axes->True,
BoundaryStyle->None,
BoxRatios->{1,1,0.5},
ViewPoint->{1.1,-2.4,1},
PerformanceGoal->"Quality"];
SetOptions[ParametricPlot,
Mesh->False,
ColorFunctionScaling->False,
Axes->False,
ImageSize->400,
Frame->False,
BoundaryStyle->None,
Epilog->{Line[{{0.85,0},{1.1,0}}],Line[{{0,0.85},{0,1.1}}],Text[Style["ϕ=0",16,FontFamily->"Arial"],{1.3,0},{0,0}],
Text[Style["ϕ=π/2",16,FontFamily->"Arial"],{0,1.2},{0,0}]},
PlotRange->{{-1.1,1.5},{-1.1,1.3}},
PerformanceGoal->"Quality"];
SetOptions[Animate,AnimationRunning->False];
SetOptions[Manipulate,BaseStyle->{FontSize->16}];
SetOptions[Manipulator,Appearance->"Labeled"];
Choose=PopupMenu[Dynamic[WaveFunctionSelector],Table[x->StringForm["ΨT``[ϕ,t]",x],{x,1,11}]];
ChosenWaveFunction[ϕ_,t_]:=ToExpression[ToString[StringForm["ΨT``[ϕ,t]",WaveFunctionSelector]]]

In this worksheet, you will examine wave functions and probability densities for a particle confined to a ring.

Define the normalized spatial eigenfunctions ((Subscript[Φ, m])(ϕ)=(1/(Sqrt[2 π]))(e^(i m ϕ))) for the particle confined to a ring.

Φ[ϕ_,m_]:=(1/Sqrt[2*Pi])*Exp[I*m*ϕ]

Multiply each spatial eigenfunction by its time dependence ((e^((-i (m^2)t)/2))) in order to construct the time-dependent states.

PhiT[ϕ_,m_]:=Exp[-I*m^2*t/2]*Φ[ϕ,m]

Here is a sample time-dependent wavefunctions consisting of a normalized linear combination of eigenstates on the ring.  You can change what wavefunction you are looking at by changing this line and then re-entering the rest of the notebook.

ΨT[ϕ_,t_]:=1/Sqrt[3]*PhiT[ϕ,1]+Sqrt[2]/Sqrt[3]*PhiT[ϕ,3]

1)  Explore which linear combinations of energy eigenstates have time dependence and what that time dependence looks like with the rest of this notebook:  
	a) Look at some individual energy eigenstates.  
	b) Explore the role of the relative phase between two terms.  
	c) Look at some linear combinations with more than two terms.

"Square" your chosen wavefunction to get the probability density.

You must evaluate the following line each time you choose a new wave function.

ΨTsq[ϕ_,t_]=FullSimplify[ComplexExpand[Conjugate[ΨT[ϕ,t]]*ΨT[ϕ,t]]];
fmax=Max[Table[ΨTsq[ϕ,0],{ϕ,0,2*π,2π/100}]];
ΨTsq[ϕ,t]

2) Does the probability density of your chosen linear combination of energy eigenstates have time dependence? Can you discern a rule?

Plot the probability density

Animate[
myplot1=Plot[ΨTsq[ϕ,t],{ϕ,0,2*Pi},PlotRange->{{0,2π},{0,fmax}}];
myplot2=ParametricPlot[{r*Cos[ϕ],r*Sin[ϕ]},{r,0.9,1},{ϕ,0,2*π},ColorFunction->Function[{x,y,r,ϕ},Hue[0.67*(1-ΨTsq[ϕ,t]/fmax)]]];
myplot3=ParametricPlot3D[{Cos[ϕ],Sin[ϕ],u*ΨTsq[ϕ,t]},{u,0,1},{ϕ,0,2*π},ColorFunction->Function[{x,y,z,u,ϕ},Hue[0.67*(1-ΨTsq[ϕ,t]/fmax)]],PlotRange->{{-1,1},{-1,1},{0,fmax}}];
Grid[{{myplot2,myplot1,myplot3}}],{t,0,Pi},AnimationRate->.1]

3a) When do probability densities rotate? In which direction do they rotate?

3b) When do probability densities not rotate? Explain.

By Corinne Manogue, Kerry Browne, Mike Vignal, and Ian Founds
Copyright 2021 Corinne Manogue